1. Основные понятия ООП

1. Инкапсуляция.
   Слово "инкапсуляция" имеет в своем корне слово "капсула".
   Отсюда становится очевидным смысл понятия инкапсуляция в программировании: защита внутренней реализации класса путем ее сокрытия за внешним интерфейсом, видимым окружающему миру.
   
   Инкапсуляция - основная концепция ООП...
   
   
2. Наследование.
   Возможность использования уже определенных объектов для построения иерархии объектов-потомков. Объект-потомок наследует от родителя ВСЕ поля и методы, и может дополнять объекты новыми полями или заменять их.
   
   
3. Полиморфизм.
   Возможность определения единого по имени действия (процедуры или функции), применимого одновременно ко всем объектам иерархии наследования, причем каждый объект может "заказывать" особенность реализации этого действия над "самим собой".

Определение объекта

type
	T = object
		{ переменные, или ПОЛЯ объекта }
		...
		{ заголовки процедур и функций, или МЕТОДЫ }
	end;

procedure ObjectType.ProcedureName(...);

type
	TA = object
		a: Integer;
		procedure give(x:integer);
	end;
{ ... }
procedure TA.give(x: integer);
begin
	a := a + x;
end;

procedure TA.give;
begin
	a := a + x;
end;

type TA = object ... end;
	
var a: TA;
begin
	a.give(5);
end.

type
	PTA = ^TA;
	TA = object ... end;

var p_a: PTA;
begin
	new(p_a);
	p_a^.give(5);
end.

Наследование

TA = 
	object
	{ поля и методы объекта TA }
	end;
TA1 =
	object(TA) { потомок TA }
	{ ... }
	end;

type
	TA = object
		x: integer;
		{...}
	end;
	TB = object(TA)
		y: integer;
		{...}
	end;
var a: TA; b: TB;

a := b;

Использование объектов

uses crt;

{ Глобальная константа }
const NN = 10;
type
	{ это наш массив, на основе которого будем делать объекты }
	atype = array[1 .. nn] of integer;

	T1 = object
		a:atype;
		n:integer;
		procedure Vec;  { процедура ввода массива }
		procedure Print; { процедура вывода массива }
	end;
	T2 = object(T1)
		s:integer; { сумма }
		procedure Print;    { перекроем новым методом, посмотрим результат }
		procedure Summ; { посчитаем сумму эл-тов }
	end;

{ ---------- теперь опишем методы ------- }
procedure T1.Vec;
var c, i: Integer;
begin
	repeat
		write('Введите длинну массива n = '); readln(n)
	until (N > 0) and (n <= NN);
	for i := 1 to n do begin
		write('a[',i,'] = '); readln(a[i])
	end
end;
{ ----- }
procedure T1.Print;
var i: Integer;
begin
	WriteLn;
	for i := 1 to n do write(a[i]:6);
	WriteLn
end;
{ ----- }
procedure T2.Print;
var F:text; fn:string; i:integer;
begin
	Writeln('Введите имя файла для записи туда массива');
	ReadLn(fn); Assign(f, fn); ReWrite(f);
	for i := 1 to n do WriteLn(f,a[i]);
	Close(f)
end;
{ ----- }
procedure T2.Summ;
var i: integer;
begin
	s := 0;
	for i := 1 to n do s := s + a[i];
end;
{ ----- }

var
	b: T1; c: T2;
	
begin
	{
	Теперь проверим работу объектов. При вызове Т2, должны быть доступны
	ВСЕ методы объекта родителя, т.е. Т1, но метод PRINT перекрывается
	}
	с.Vec;
	b.Print;
	c.Print;
	c.Summ;
end.

c.Vec

2. Виртуальные методы

uses crt;
Type
  _A = Object
    per:integer;
    constructor Init;
    procedure P; virtual;
    procedure run;
  end;

  _B = Object(_A)
    constructor INIT;
    procedure P; virtual;
  end;

constructor _A.INIT;
begin per:=0 end;
procedure _A.P;
begin end;
procedure _A.RUN;
begin P end;

constructor _B.INIT;
begin per:=0 end;
Procedure _B.p;
begin per:=5; writeln(per) end;

Var
  A:_A; B:_B;
Begin
  Clrscr;
  B.INIT;
  B.run;
end.

B.run;

Procedure _A.P; begin end;

procedure P; virtual;

1. Если прародитель описывает метод, как виртуальный, то он должен описываться как виртуальный и во всех потомках. Другими словами, виртуальный метод не может заменяться статическим (при попытке это сделать компилятор выдаст ошибку #149: VIRTUAL expected - "Ожидается служебное слово Virtual"). Обратное переопределение (преобразование статической функции в виртуальную) вполне допустимо.
2. Если переопределяется реализация виртуального метода, то его заголовок должен остаться неизменным (т.е. НЕ должны изменяться порядок расположения, количество и типы формальных параметров в одноименных виртуальных методах). При изменении заголовка компилятор выдаст ошибку #131: Header does not match previous definition - "Заголовок не соответствует предыдущему описанию"

Конструкторы и деструкторы

Type {....}
  Procedure {.....}
  Destructor {Name}
  {....}

1. Делайте метод виртуальным, если существует вероятность его переопределения. Это должно обеспечить расширяемость программ
2. Скорость выполнения программы: при наличии в объекте хотя бы одного виртуального метода для него создается VMT и обращения к виртуальным методам происходят через эту таблицу; статические методы вызываются напрямую (без обращения к VMT). Если же объект вообще не содержит виртуальных методов, то VMT для этого типа создана не будет.

3. Динамические объектные типы

uses crt;
Type
  _A = Object
    per:integer;
    constructor Init;
    procedure P; virtual;
    procedure run;
  end;
  _B = Object(_A)
    constructor INIT;
    procedure P; virtual;
  end;

constructor _A.INIT;
begin per:=0 end;
Procedure _A.P;
begin end;
procedure _A.RUN;
begin P end;

constructor _B.INIT;
begin per:=0 end;
Procedure _B.p;
begin per:=5; writeln(per) end;

Var
  A:_A; B:_B;
Begin
  Clrscr;
  B:=New(_B, INIT);
  B^.run;
end.

Обработка ошибок при работе с объектами

{ Динамический объект }
Type
  arrType = Array[1 .. 1000] of Integer;
  PTArray = ^TArray;
  TArray = Object
    A: ^arrType;
    Constructor Init;
    Destructor Done; Virtual;
    ...
  End;

Constructor TArray.Init;
begin
  new(A);

  { Если будет обнаружена нехватка памяти }
  if A = nil then begin
    TArray.Done; Fail { Производим откат }
  end;
end;

var arr: PTArray;
begin
  new(arr, init); { Если в конструкторе обнаружилась нехватка памяти }
  If arr = nil then halt(1); { выйти из программы }
end.

{ Статический объект }
Type
  arrType = Array[1 .. 1000] of Integer;
  TArray = Object
    A: ^arrType;
    Constructor Init;
    Destructor Done; Virtual;
    ...
  End;

Constructor TArray.Init;
begin
  new(A);

  { Если будет обнаружена нехватка памяти }
  if A = nil then begin
    TArray.Done; Fail { Производим откат }
  end;
end;

Var arr: PTArray;
begin
  If not arr.Init { Если в конструкторе обнаружилась нехватка памяти }
    Then halt(2); { выйти из программы }
end.

Функция TypeOf

TypeOf(ИмяЭкземпляра_или_ИмяТипа): Pointer;

type
  a = object
    p: integer;
    constructor init;
    procedure x; virtual;
  end;

  b = object(a)
    constructor init;
  end;

constructor a.init;
begin end;
constructor b.init;
begin end;

procedure a.x;
begin end;

procedure check(var x: a);
begin
  if typeof(x) = typeof(a) then
    writeln('the object is A')
  else writeln('the object is B')
end;

var
  _a: A;
  _b: B;
begin
  _a.init; _b.init;
  check(_a);
  check(_b);
end.

Стартовые значения для объектов

Type a = object
  x, y: integer;
  constructor init;
  ...
  destructor done; virtual;
end;

const
  a_1: a = (x: 3; y: 4);
  a_2: a = (x: 4; y: 7);

Type a = object
  _x, _y: integer;
  constructor Copy(x: a);
  ...
end;
constructor a.Copy(x: a);
begin self := x end;

const
  c_a: a = { инициализация начальных значений объекта }
...
{ далее в программе можно использовать инициализацию вида: }
var
  v_a: a;
...
v_a.Copy(c_a);

Структура VMT

  SizeOfInstance:Integer;   {Размер экземпляра класса}
  MSizeOfInstance:Integer; { = -SizeOfInstance}
  DMTOffset:Word;             {Смещение DMT}
  Zero:Word;                     {Всегда 0}
  Methods:Array Of Pointer  {Адреса методов}

  ParentDMTOffset:Word;    {Смещение DMT класса-родителя}

  {Кэшируемый индекс - индекс последнего вызванного метода}
  CacheIndex:Word;
  {Смещение в этом сегменте Pointer'а, который
    хранит адрес последнего вызванного метода }
  CacheAddr:Word;

  TableSize:Word;               {Кол-во эл-тов в таблице}
  Indexes:Array Of Word;
  Methods:Array Of Pointer;

• Статический:

    LES DI,[Instance]
    PUSH ES
    PUSH DI           { Self передаём }
    CALL TypeName.MethodName

• Виртуальный:

    LES DI,[Instance]
    PUSH ES
    PUSH DI
    MOV DI,[ES:DI + VMTOffset]
    {VMTOffset = сумма размеров всех полей "самого базового" класса}
    CALL [DWORD PTR DI + OffsetOfMethodInVMT] {= 4*номер по счёту}

• Динамический:

    LES DI,[Instance]
    PUSH ES
    PUSH DI
    MOV DI,[ES:DI + VMTOffset]
    MOV AX,MethodIndex
    PUSH AX
    CALL Dispatch

  И пусть этот Dispatch сам себе мозги компостирует и ищет чего там вызвать надо.